
 1000  *---------------------------------
 1010  *      MULTIPLY TWO BYTES BY TEN
 1020  *---------------------------------
 1030  B0     .EQ $00
 1040  B1     .EQ $01
 1050  BY.TEN LDA B1       SAVE HI-BYTE ON STACK
 1060         PHA
 1070         LDA B0       GET LO-BYTE IN A
 1080         ASL B0       DOUBLE THE TWO-BYTE VALUE
 1090         ROL B1
 1100         ASL B0       DOUBLE IT AGAIN
 1110         ROL B1
 1120         CLC          ADD IN THE ORIGINAL VALUE
 1130         ADC B0
 1140         STA B0       LO-BYTE
 1150         PLA          HI-BYTE
 1160         ADC B1
 1170         STA B1
 1180         ASL B0       DOUBLE 5*B TO GET 10*B
 1190         ROL B1
 1200         RTS          RETURN TO CALLER

