
 1000  *SAVE CHECKSUMMER
 1010  *--------------------------------
 1020         .OR $267C    POSITION IN PRODOS SYSTEM FILE
 1030  *--------------------------------
 1040  CHECKSUMMER
 1050         CLC
 1060         LDY $2674    (GETS A VALUE 0)
 1070  .1     LDA ($0A),Y  GETS (FB09...FB10)
 1080         AND #$DF     STRIP OFF LOWER CASE BIT
 1090         ADC $2674    ACCUMULATE SHIFTED SUM
 1100         STA $2674
 1110         ROL $2674    SHIFT RESULT, CARRY INTO BIT 0
 1120         INY
 1130         CPY $2677    DO IT 8 TIMES
 1140         BNE .1
 1150         TYA          A = Y = 8
 1160         ASL          FORM $80 BY SHIFTING
 1170         ASL
 1180         ASL
 1190         ASL
 1200         TAY          $80 TO Y FOR LATER TRICK
 1210         EOR $2674    MERGE WITH PREVIOUS "SUM"
 1220         ADC #11      FORM $00 FOR VALID ROMS
 1230         BNE .2       ...NOT A VALID ROM
 1240         LDA $0C      GET MACHINE ID BYTE
 1250         RTS
 1260  .2     LDA #0       SIGNAL INVALIDITY
 1270         RTS

