
 1000  *---------------------------------
 1010  *      PATCHES TO ADD ASCII DUMP
 1020  *      TO THE APPLE MONITOR
 1030  *---------------------------------
 1040  A1L        .EQ $3C
 1050  COUT       .EQ $FDED
 1060  *---------------------------------
 1070         .OR $FDB8
 1080         .TA $0DB8
 1090         JSR PATCH    CALL MY PATCH CODE
 1100  *---------------------------------
 1110         .OR $FCC9
 1120         .TA $0CC9
 1130  PATCH
 1140         JSR COUT     PRINT A SPACE
 1150         LDA (A1L),Y  GET BYTE TO BE DISPLAYED
 1160         PHA          SAVE IT ON STACK
 1170         LDA A1L      LOW BYTE OF DUMP ADDRESS
 1180         AND #7       MASK LINE POSITION
 1190         CLC
 1200         ADC #31      COMPUTE HORIZONTAL OFFSET
 1210         TAY
 1220         PLA          GET BYTE FROM STACK
 1230         STA ($28),Y  STORE IT ON THE SCREEN
 1240         LDY #0       RESTORE Y
 1250         RTS

