
 1000  *--------------------------------
 1010  *      "SHOW" COMMAND
 1020  *--------------------------------
 1030  DOS.OPEN.TEXT.FILE  .EQ $A2A3
 1040  DOS.CLOSE.FILE      .EQ $A2FC
 1050  DOS.READ.ONE.BYTE   .EQ $A68C
 1060  KEYBOARD            .EQ $C000
 1070  STROBE              .EQ $C010
 1080  MON.COUT1           .EQ $FDF0
 1090  *--------------------------------
 1100         .OR $A54F
 1110         .TA $84F
 1120  SHOW
 1130         JSR DOS.OPEN.TEXT.FILE
 1140         LDA #$8D
 1150  .1     JSR MON.COUT1
 1160         JSR PAUSE.CHECK
 1170         BEQ .2
 1180         JSR DOS.READ.ONE.BYTE
 1190         BNE .1       PRINT IT
 1200  .2     JMP DOS.CLOSE.FILE
 1210  *--------------------------------
 1220  *      RETURN .EQ. IF ABORT
 1230  *             .NE. IF CONTINUE
 1240  *--------------------------------
 1250         .OR $AE8E         OVER "INIT" CODE
 1260         .TA $88E
 1270  PAUSE.CHECK
 1280         LDA KEYBOARD      ANY KEY PRESSED?
 1290         BPL .2            NO, CONTINUE
 1300         STA STROBE        YES, CLEAR STROBE
 1310         CMP #$8D          ABORT?
 1320         BEQ .2            YES, RETURN .EQ. STATUS
 1330  .1     LDA KEYBOARD      NO, PAUSE TILL KEYPRESS
 1340         BPL .1            NONE PRESSED YET
 1350         STA STROBE        CLEAR STROBE
 1360         CMP #$8D          ABORT?
 1370  .2     RTS               .EQ. IF ABORT
 1380  *--------------------------------
 1390         .OR $A884
 1400         .TA $884
 1410         .AT /SHOW/   SHOW COMMAND NAME
 1420  *--------------------------------
 1430         .OR $A909
 1440         .TA $809
 1450         .HS 2030     FLAGS FOR SHOW COMMAND
 1460  *--------------------------------

