
 1000  *SAVE S.AMPER.MONITOR
 1010  *--------------------------------
 1020  *      &-MONITOR COMMANDS
 1030  *--------------------------------
 1040  MON.MODE         .EQ $31
 1050  MON.YSAV         .EQ $34
 1060  TXTPTR           .EQ $B8 AND B9
 1070  MON.BUFFER       .EQ $200
 1080  AMPERSAND.VECTOR .EQ $3F5
 1090  *--------------------------------
 1100  AS.CHRGET        .EQ $00B1
 1110  AS.SYNERR        .EQ $DEC9
 1120  MON.BL1          .EQ $FE00
 1130  MON.GETNUM       .EQ $FFA7
 1140  MON.TOSUB        .EQ $FFBE
 1150  MON.ZMODE        .EQ $FFC7
 1160  MON.CHRTBL       .EQ $FFCC
 1170  *--------------------------------
 1180         .OR $300
 1190  *--------------------------------
 1200  SETUP  LDA #AMPER.MONITOR
 1210         STA AMPERSAND.VECTOR+1
 1220         LDA /AMPER.MONITOR
 1230         STA AMPERSAND.VECTOR+2
 1240         RTS
 1250  *--------------------------------
 1260  AMPER.MONITOR
 1270         CMP #$22     MUST BE QUOTATION MARK HERE
 1280         BNE .6       SYNTAX ERROR
 1290         JSR AS.CHRGET
 1300         LDY #0
 1310  .1     LDA (TXTPTR),Y
 1320         BEQ .2
 1330         ORA #$80
 1340         STA MON.BUFFER,Y
 1350         INY
 1360         BNE .1
 1370  .2     LDA #$8D
 1380         STA MON.BUFFER,Y
 1390         TYA
 1400         CLC
 1410         ADC TXTPTR
 1420         STA TXTPTR
 1430         BCC .25
 1440         INC TXTPTR+1
 1450  .25    JSR MON.ZMODE
 1460  .3     JSR MON.GETNUM
 1470         STY MON.YSAV
 1480         LDY #23
 1490  .4     DEY
 1500         BMI .6       SYNTAX ERROR
 1510         CMP MON.CHRTBL,Y
 1520         BNE .4       NOT THIS ENTRY
 1530         CPY #21
 1540         BEQ .5       <RETURN> ALONE
 1550         JSR MON.TOSUB
 1560         LDY MON.YSAV
 1570         JMP .3
 1580  .5     JSR MON.ZMODE-2
 1590         JMP MON.BL1
 1600  .6     JMP AS.SYNERR

