
 1000  *SAVE SATHER 3-16
 1010  *--------------------------------
 1020  *      HIRES-LORES SPLIT
 1030  *      SATHER 3-16
 1040  *--------------------------------
 1050  KYBD     .EQ $C000
 1060  STRB     .EQ $C010
 1070  GRAPHICS .EQ $C050
 1080  TEXT     .EQ $C051
 1090  NOTMIXED .EQ $C052
 1100  PAGE1    .EQ $C054
 1110  LORES    .EQ $C056
 1120  *--------------------------------
 1130  *      TOGGLE HI/LO-RES EVERY 8515 CYCLES
 1140  *--------------------------------
 1150         .OR $300
 1160  SPLIT  LDY PAGE1    HI/LO PAGE 1
 1170         LDY NOTMIXED
 1180         LDY GRAPHICS
 1190  *--------------------------------
 1200  SLEW   LDY #39      (2)    SLEW SCREEN IF KEY PRESSED
 1210         JSR WAITX10  (390)  6*65+7 CYCLES
 1220         LDY STRB     (4)
 1230  *--------------------------------
 1240  KEYCHK LDY KYBD     (4)    ANY KEY PRESSED?
 1250         BMI SLEW     (2 OR 3)  YES, SLEW ONE LINE
 1260         ADC #1       (2)    MAKE ALTERNATING 0 AND 1
 1270         AND #1       (2)
 1280         TAX          (2)    REMEMBER, 0 OR 1
 1290         LDY LORES,X  (4)    LORES IF X=0, HIRES IF X=1
 1300         LDX #8       (2)
 1310         JSR WAITX1K  (8000)
 1320         LDY #49      (2)
 1330         JSR WAITX10  (490)
 1340         CLC          (2)
 1350         BCC KEYCHK   (3)    ...ALWAYS
 1360  *                   ======
 1370  *                   (8515)
 1380  *
 1390  *--------------------------------
 1400  *      TIMING ROUTINES
 1410  *--------------------------------
 1420  *
 1430  *---WAIT 10Y CYCLES--------------
 1440  *---(INCLUDING JSR)--------------
 1450  WAITX10  DEY        (2)  WAIT Y-REG TIMES 10
 1460  .1       DEY        (2)
 1470           NOP        (2)
 1480           BNE .2     (3 OR 2)
 1490           RTS        (6)
 1500  .2       BNE .1     (3)  ...ALWAYS
 1510  *--------------------------------
 1520  *
 1530  *---WAIT 1000X CYCLES------------
 1540  *---(INCLUDING JSR)--------------
 1550  LOOP1K   PHA        (3)
 1560           PLA        (4)
 1570           NOP        (2)
 1580           NOP        (2)
 1590  WAITX1K  LDY #98    (2)  WAIT X-REG TIMES 1000
 1600           JSR WAITX10 (980)
 1610           NOP        (2)
 1620           DEX        (2)
 1630           BNE LOOP1K (3 OR 2)
 1640           RTS        (6)
 1650  *--------------------------------
 1660  *--------------------------------
 1670  *      HORIZONTAL SPLIT
 1680  *      BY BOB SANDER-CEDERLOF
 1690  *--------------------------------
 1700  HSPLIT
 1710         LDA GRAPHICS (4    4)
 1720         LDA KYBD     (4    4)    SEE IF SHOULD SLEW
 1730         BPL .1       (3    2)
 1740         STA STRB          (4)
 1750         BMI .3            (3)
 1760  .1     NOP          (2)
 1770         BPL .3       (3)
 1780  .3     JSR DLY12    (12  12)
 1790         NOP          (2    2)
 1800         NOP          (2    2)
 1810  *                   ---  ---
 1820  *                   (32  33)
 1830  *
 1840         LDA TEXT     (4)
 1850         JSR DLY21    (21)
 1860         CLC          (2)
 1870         BCC .2       (3)
 1880  .2     BCC HSPLIT   (3)
 1890  *                   ----
 1900  *                   (33)
 1910  *
 1920  *--------------------------------
 1930  *      JSR DLY..    (6)     (6)
 1940  DLY21  PHA          (3)
 1950         PLA          (4)
 1960         NOP          (2)
 1970  DLY12  RTS          (6)     (6)
 1980  *                   ----   ----
 1990  *                   (21)   (12)

