
 1000  *SAVE S.BUILD.PRESHIFT.TABLES
 1010  *--------------------------------
 1020  *   WRITTEN BY G. L. POMPONI, PISA, ITALY
 1030  *   MODIFIED BY BOB SANDER-CEDERLOF
 1040  *--------------------------------
 1050  L.BYTE .EQ 0
 1060  R.BYTE .EQ 1
 1070  *--------------------------------
 1080             .OR $900
 1090  SHIFT.1    .BS 128
 1100  SHIFT.2    .BS 128
 1110  SHIFT.3    .BS 128
 1120  SHIFT.4    .BS 128
 1130  SHIFT.5    .BS 128
 1140  SHIFT.6    .BS 128
 1150  *--------------------------------
 1160  REMND.1    .BS 128
 1170  REMND.2    .BS 128
 1180  REMND.3    .BS 128
 1190  REMND.4    .BS 128
 1200  REMND.5    .BS 128
 1210  REMND.6    .BS 128
 1220  *--------------------------------
 1230         .MA SHIFT
 1240         ASL L.BYTE
 1250         ROL R.BYTE
 1260         LDA L.BYTE
 1270         LSR
 1280         STA SHIFT.]1,X
 1290         LDA R.BYTE
 1300         STA REMND.]1,X
 1310         .EM
 1320  *--------------------------------
 1330         .OR $800
 1340  *--------------------------------
 1350  BUILD.PRESHIFT.TABLES
 1360         LDX #0       FOR X = 0 TO $7F
 1370  *--------------------------------
 1380  .1     STX L.BYTE
 1390         LDA #0
 1400         STA R.BYTE
 1410         ASL L.BYTE
 1420  *--------------------------------
 1430         >SHIFT 1
 1440         >SHIFT 2
 1450         >SHIFT 3
 1460         >SHIFT 4
 1470         >SHIFT 5
 1480         >SHIFT 6
 1490  *--------------------------------
 1500         INX          NEXT X
 1510         BPL .1       (...UNTIL $80)
 1520         RTS
 1530  *--------------------------------
 1540  *   BUILDS 1000 TIMES IN LESS THAN 24 SECONDS,
 1550  *      SO LESS THAN 24 MILLISECONDS TO BUILD ONCE
 1560  *--------------------------------
 1570  TIME   LDA #4       4*250 = 1000
 1580         STA $500
 1590  .1     LDY #250
 1600  .2     JSR BUILD.PRESHIFT.TABLES
 1610         DEY
 1620         BNE .2
 1630         DEC $500
 1640         BNE .1
 1650         RTS
 1660  *--------------------------------

