
 1000  *SAVE S.RWTS.SNOOPER
 1010  *--------------------------------
 1020  PRBYTE .EQ $FDDA
 1030  CROUT  .EQ $FD8E
 1040  COUT   .EQ $FDED
 1050  *--------------------------------
 1060  INSTALL.SNOOPER
 1070         LDX #1
 1080  .1     LDA DRIVER,X
 1090         PHA
 1100         LDA $B091,X
 1110         STA DRIVER,X
 1120         PLA
 1130         STA $B091,X
 1140         DEX
 1150         BPL .1
 1160         RTS
 1170  *--------------------------------
 1180  DRIVER .DA SNOOPER  MODIFIED DURING OPERATION
 1190  *--------------------------------
 1200  SNOOPER
 1210         LDA $778
 1220         STA SAVE778
 1230         LDA $7F8
 1240         STA SAVE7F8
 1250  *--------------------------------
 1260         TSX
 1270         JSR CROUT
 1280         JSR PRADDR   PRINT RETURN ADDR FROM STACK
 1290         JSR PRADDR   AND ANOTHER ONE
 1300  *--------------------------------
 1310         LDA $B7F4    COMMAND
 1320         JSR BYTE
 1330         LDA $B7EC    TRACK
 1340         JSR BYTE
 1350         LDA $B7ED    SECTOR
 1360         JSR BYTE
 1370         LDA $B7F1    BUFFER ADDRESS
 1380         JSR PRBYTE
 1390         LDA $B7F0
 1400         JSR PRBYTE
 1410  *--------------------------------
 1420         LDA SAVE778
 1430         STA $778
 1440         LDA SAVE7F8
 1450         STA $7F8
 1460         LDA $AAC2
 1470         LDY $AAC1
 1480         JMP (DRIVER)
 1490  *--------------------------------
 1500  PRADDR
 1510         LDA $108,X
 1520         JSR PRBYTE
 1530         LDA $107,X
 1540         DEX          SET UP FOR NEXT ADDRESS
 1550         DEX
 1560  BYTE   JSR PRBYTE
 1570         LDA #"."
 1580         JMP COUT
 1590  *--------------------------------
 1600  SAVEX  .BS 1
 1610  SAVEY  .BS 1
 1620  SAVE778 .BS 1
 1630  SAVE7F8 .BS 1
 1640  *--------------------------------

