
 1000  *SAVE S.LORES TO HIRES
 1010  *--------------------------------
 1020  LBAS   .EQ $26,27
 1030  HBAS   .EQ $2A,2B
 1040  SAVEX  .EQ $2E
 1050  COLOR  .EQ $30
 1060  *--------------------------------
 1070  T
 1080         JSR PLOT
 1090         LDA $C050    GRAPHICS
 1100         LDA $C052    SOLID (40 BY 48 PIXELS)
 1110         LDA $C054    PRIMARY PAGE
 1120  .1     LDA $C056    LO-RES
 1130         JSR PAUSE.FOR.ANY.KEY
 1140         BEQ .2       ...<RETURN>
 1150         LDA $C057    HIRES
 1160         JSR CONVERT
 1170         JSR PAUSE.FOR.ANY.KEY
 1180         BNE .1       ...NOT <RETURN>
 1190  .2     LDA $C051    TEXT
 1200         RTS
 1210  *--------------------------------
 1220  PAUSE.FOR.ANY.KEY
 1230  .1     LDA $C000    WAIT FOR ANY KEY
 1240         BPL .1       ...NOT YET
 1250         STA $C010    CLEAR STROBE
 1260         CMP #$8D     SET .EQ. IF <RETURN>
 1270         RTS
 1280  *--------------------------------
 1290  CONVERT
 1300         LDX #23      OR #19 IF MIXED MODE
 1310  .1     LDY #39      COLUMNS 0...39
 1320         LDA LOL,X    SET UP BASE POINTER FOR LINE
 1330         STA LBAS
 1340         STA HBAS     SAME FOR HI-RES
 1350         LDA LOH,X
 1360         STA LBAS+1
 1370         EOR #$24     SHIFT FROM $400 TO $2000 FOR HI-RES
 1380         STA HBAS+1
 1390         STX SAVEX    SAVE X-REG
 1400  .2     LDA (LBAS),Y GET TWO LO-RES PIXELS
 1410         PHA          SAVE FOR LOWER ONE
 1420         ASL          UPPER PIXEL * 8
 1430         ASL
 1440         ASL
 1450         JSR PROCESS.NYBBLE
 1460         PLA          GET LOWER PIXEL
 1470         LSR          TIMES 8
 1480         JSR PROCESS.NYBBLE
 1490         DEY          NEXT COLUMN, SCANNING RIGHT TO LEFT
 1500         BPL .2       ...ANOTHER ONE
 1510         LDX SAVEX    RESTORE X-REG
 1520         DEX          NEXT LINE, SCANNING BOTTOM TO TOP
 1530         BPL .1       ...ANOTHER ONE
 1540         RTS          FINISHED!
 1550  *--------------------------------
 1560  LOH    .HS 04.04.05.05.06.06.07.07  HIGH BYTES
 1570         .HS 04.04.05.05.06.06.07.07  OF SCRN PNTRS
 1580         .HS 04.04.05.05.06.06.07.07  (TEXT OR LO-RES)
 1590  *--------------------------------
 1600  LOL    .HS 00.80.00.80.00.80.00.80  LOW BYTES
 1610         .HS 28.A8.28.A8.28.A8.28.A8  OF SCRN PNTRS
 1620         .HS 50.D0.50.D0.50.D0.50.D0
 1630  *--------------------------------
 1640  PROCESS.NYBBLE
 1650         AND #$78     MASK THE SHIFTED NYBBLE
 1660         STA COLOR
 1670         TYA          LO-RES COLUMN
 1680         AND #3       LOW 2 BITS
 1690         ORA COLOR         0CCCC0YY
 1700         TAX
 1710         JSR COMMON.CODE
 1720         EOR #$0C          3RD LINE OF 4
 1730         STA HBAS+1
 1740         JSR COMMON.CODE
 1750         EOR #$1C          NEXT LINE
 1760         STA HBAS+1
 1770         RTS
 1780  *--------------------------------
 1790  COMMON.CODE
 1800         LDA SHADES,X      EVEN LINE
 1810         STA (HBAS),Y
 1820         LDA HBAS+1
 1830         ORA #4
 1840         STA HBAS+1
 1850         LDA SHADES+4,X    ODD LINE
 1860         STA (HBAS),Y
 1870         LDA HBAS+1
 1880         RTS
 1890  *--------------------------------
 1900  SHADES .HS 00.00.00.00.00.00.00.00  0--BLACK
 1910         .HS AA.D5.AA.D5.55.2A.55.2A  1--MAGENTA
 1920         .HS 91.A2.C4.88.C4.88.91.A2  2--DARK BLUE
 1930         .HS 11.22.44.08.44.08.11.22  3--PURPLE
 1940         .HS 2A.55.2A.55.2A.55.2A.55  4--DARK GREEN
 1950         .HS 33.66.4C.19.4C.19.33.66  5--GRAY 1
 1960         .HS D5.AA.D5.AA.D5.AA.D5.AA  6--MEDIUM BLUE
 1970         .HS DD.BB.F7.EE.F7.EE.DD.BB  7--LIGHT BLUE
 1980         .HS A2.C4.88.91.88.91.A2.C4  8--BROWN
 1990         .HS AA.D5.AA.D5.AA.D5.AA.D5  9--ORANGE
 2000         .HS B3.E6.CC.99.CC.99.B3.E6  A--GRAY 2
 2010         .HS D5.AA.D5.AA.AA.D5.AA.D5  B--PINK
 2020         .HS 6E.5D.3B.77.3B.77.6E.5D  C--LIGHT GREEN
 2030         .HS 2A.55.2A.55.AA.D5.AA.D5  D--YELLOW
 2040         .HS 2A.55.2A.55.D5.AA.D5.AA  E--AQUAMARINE
 2050         .HS 7F.7F.7F.7F.7F.7F.7F.7F  F--WHITE
 2060  *--------------------------------
 2070  *   FILL CORNER WITH SAMPLES OF EACH COLOR
 2080  *--------------------------------
 2090  PLOT   LDY #0
 2100         STY COLOR
 2110  .1     LDX #3
 2120  .2     LDA COLOR    00, 44, 88, CC
 2130         STA $400,Y   GR ROWS 0-3
 2140         STA $480,Y
 2150         CLC
 2160         ADC #$11     11, 55, 99, DD
 2170         STA $500,Y   GR ROWS 4-7
 2180         STA $580,Y
 2190         ADC #$11     22, 66, AA, EE
 2200         STA $600,Y   GR ROWS 8-11
 2210         STA $680,Y
 2220         ADC #$11     33, 77, BB, FF
 2230         STA $700,Y   GR ROWS 12-15
 2240         STA $780,Y
 2250         INY
 2260         DEX
 2270         BPL .2
 2280         ADC #$11     .., 44, 88, CC, END
 2290         STA COLOR
 2300         BCC .1       ...MORE
 2310         RTS
 2320  *--------------------------------

